Trident validate

modules/nf-core/trident/validate/environment.yml

@@ -0,0 +1,7 @@
+---
+# yaml-language-server: $schema=https://raw.githubusercontent.com/nf-core/modules/master/modules/environment-schema.json
+channels:
+  - conda-forge
+  - bioconda
+dependencies:
+  - "bioconda::poseidon-trident=2.2.2.1"

modules/nf-core/trident/validate/main.nf

@@ -0,0 +1,37 @@
+process TRIDENT_VALIDATE {
+    tag "${meta.id}"
+    label 'process_single'
+
+    conda "${moduleDir}/environment.yml"
+    container "${workflow.containerEngine == 'singularity' && !task.ext.singularity_pull_docker_container
+        ? 'https://depot.galaxyproject.org/singularity/poseidon-trident:2.2.2.1--hf7d7819_0'
+        : 'quay.io/biocontainers/poseidon-trident:2.2.2.1--hf7d7819_0'}"
+
+    input:
+    // Inputs need to be synchronised so that all files for a given package are provided together.
+    tuple val(meta), path(input_package)
+
+    output:
+    tuple val(meta), path(input_package), env("EXIT_CODE"), emit: validated_packages
+    tuple val("${task.process}"), val('trident'), eval('trident --version'), emit: versions_trident, topic: versions
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def args = task.ext.args ?: ''
+    """
+    trident validate \
+        -d . \
+        ${args} || EXIT_CODE=\$?
+
+    EXIT_CODE=\${EXIT_CODE:-0}
+    """
+
+    stub:
+    def args = task.ext.args ?: ''
+    """
+    EXIT_CODE=0
+    echo trident validate -d . ${args}
+    """
+}

modules/nf-core/trident/validate/meta.yml

@@ -0,0 +1,66 @@
+name: "trident_validate"
+description: Check Poseidon packages or package components for structural correctness
+keywords:
+  - poseidon-trident
+  - poseidon
+  - trident
+  - validate
+tools:
+  - "trident":
+      description: "A tool (trident) to work with modular genotype databases formatted using Poseidon."
+      homepage: "https://www.poseidon-adna.org/"
+      documentation: "https://www.poseidon-adna.org/#/trident?id=validate-command"
+      tool_dev_url: "https://github.com/poseidon-framework/poseidon-hs/"
+      doi: "10.7554/eLife.98317.1"
+      licence:
+        - "MIT"
+      identifier: ""
+
+input:
+  - - meta:
+        type: map
+        description: |
+          Groovy Map containing sample information
+          e.g. [ id:'test', version: "2.1.0", snpSet: "1240K", format:'EIGENSTRAT' ]
+    - input_package:
+        type: directory
+        description: Path to the directory containing the Poseidon package(s) to be validated.
+output:
+  validated_packages:
+    - - meta:
+          type: map
+          description: The meta information of the input package.
+      - input_package:
+          type: directory
+          description: Path to the directory containing the Poseidon package(s) that was validated.
+      - EXIT_CODE:
+          type: string
+          description: Exit code (0 for success, non-zero otherwise) that is the result of the validation check.
+          ontologies: []
+  versions_trident:
+    - - ${task.process}:
+          type: string
+          description: The name of the process
+      - trident:
+          type: string
+          description: The name of the tool
+      - trident --version:
+          type: eval
+          description: The expression to obtain the version of the tool
+
+topics:
+  versions:
+    - - ${task.process}:
+          type: string
+          description: The name of the process
+      - trident:
+          type: string
+          description: The name of the tool
+      - trident --version:
+          type: eval
+          description: The expression to obtain the version of the tool
+
+authors:
+  - "@TCLamnidis"
+maintainers:
+  - "@TCLamnidis"

modules/nf-core/trident/validate/tests/main.nf.test

@@ -0,0 +1,103 @@
+nextflow_process {
+
+    name "Test Process TRIDENT_VALIDATE"
+    script "../main.nf"
+    process "TRIDENT_VALIDATE"
+
+    tag "modules"
+    tag "modules_nfcore"
+    tag "trident"
+    tag "trident/fetch"
+    tag "trident/validate"
+
+    test('Validate 2012_MeyerScience-2.1.1 & 2018_Lamnidis_Fennoscandia-2.1.1') {
+
+        setup {
+            run("TRIDENT_FETCH") {
+                script "../../fetch/main.nf"
+                process {
+                    """
+                    input[0] = channel.fromList([
+                        tuple(
+                            [], // archive_dir
+                            '*2012_MeyerScience-2.1.1*,*2018_Lamnidis_Fennoscandia-2.1.1*', // fetchString
+                            [], // fetchFile
+                        )
+                    ])
+                    """
+                }
+            }
+        }
+
+        when {
+            process {
+                """
+                input[0] = TRIDENT_FETCH.out.downloaded_packages
+                    .flatMap()
+                    .map{
+                        fn ->
+                        def parts = fn.name.split(/-(?=\\d+\\.)/, 2)
+                        def id = parts[0]
+                        def version = parts.size() > 1 ? parts[1] : ''
+                        [[id: id, version: version], fn]
+                    }
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(sanitizeOutput(process.out)).match() }
+            )
+        }
+
+    }
+
+    test('Validate 2012_MeyerScience-2.1.1 - stub') {
+
+        options "-stub"
+
+        setup {
+            run("TRIDENT_FETCH") {
+                script "../../fetch/main.nf"
+                process {
+                    """
+                    input[0] = channel.fromList([
+                        tuple(
+                            [], // archive_dir
+                            '*2012_MeyerScience-2.1.1*', // fetchString
+                            [], // fetchFile
+                        )
+                    ])
+                    """
+                }
+            }
+        }
+
+        when {
+            process {
+                """
+                input[0] = TRIDENT_FETCH.out.downloaded_packages
+                    .flatMap()
+                    .map{
+                        fn ->
+                        def parts = fn.name.split(/-(?=\\d+\\.)/, 2)
+                        def id = parts[0]
+                        def version = parts.size() > 1 ? parts[1] : ''
+                        [[id: id, version: version], fn]
+                    }
+                """
+            }
+        }
+
+        then {
+            assertAll(
+                { assert process.success },
+                { assert snapshot(sanitizeOutput(process.out)).match() }
+            )
+        }
+
+    }
+
+}

modules/nf-core/trident/validate/tests/main.nf.test.snap

@@ -0,0 +1,92 @@
+{
+    "Validate 2012_MeyerScience-2.1.1 - stub": {
+        "content": [
+            {
+                "validated_packages": [
+                    [
+                        {
+                            "id": "dummy_package_dir"
+                        },
+                        [
+                            "POSEIDON.yml:md5,d41d8cd98f00b204e9800998ecf8427e",
+                            "dummy_package.geno:md5,d41d8cd98f00b204e9800998ecf8427e",
+                            "dummy_package.ind:md5,d41d8cd98f00b204e9800998ecf8427e",
+                            "dummy_package.janno:md5,d41d8cd98f00b204e9800998ecf8427e",
+                            "dummy_package.snp:md5,d41d8cd98f00b204e9800998ecf8427e"
+                        ],
+                        "0"
+                    ]
+                ],
+                "versions_trident": [
+                    [
+                        "TRIDENT_VALIDATE",
+                        "trident",
+                        "2.2.2.1"
+                    ]
+                ]
+            }
+        ],
+        "timestamp": "2026-11-03T14:43:12.379249",
+        "meta": {
+            "nf-test": "0.9.5",
+            "nextflow": "26.10.4"
+        }
+    },
+    "Validate 2012_MeyerScience-2.1.1 & 2018_Lamnidis_Fennoscandia-2.1.1": {
+        "content": [
+            {
+                "validated_packages": [
+                    [
+                        {
+                            "id": "2012_MeyerScience",
+                            "version": "2.1.1"
+                        },
+                        [
+                            "2012_MeyerScience.bed:md5,781fbf7f4573cd286133457690b0ddb3",
+                            "2012_MeyerScience.bib:md5,db334a66b02319ec8dd100bfdd9dc725",
+                            "2012_MeyerScience.bim:md5,1fa4fd6b43fdf93bdda133d42d56f78d",
+                            "2012_MeyerScience.fam:md5,0c6a50cb207e46e01d89a295ee6ab91e",
+                            "2012_MeyerScience.janno:md5,e6d97237e0c1a450614637a7a37a58ef",
+                            "CHANGELOG.md:md5,12369b9ea26f7e2a3b7a119ad729bc59",
+                            "POSEIDON.yml:md5,cfdaca8ddb5ee14bc8d8baeb8b8c5622"
+                        ],
+                        "0"
+                    ],
+                    [
+                        {
+                            "id": "2018_Lamnidis_Fennoscandia",
+                            "version": "2.1.1"
+                        },
+                        [
+                            "2018_Lamnidis_Fennoscandia.bed:md5,74d8d52d45a0d2f6ed1212af5d2f4268",
+                            "2018_Lamnidis_Fennoscandia.bib:md5,4c5ee1f871c1096a6c75101a08448377",
+                            "2018_Lamnidis_Fennoscandia.bim:md5,10fe736b07171086524ec92dc5e06a22",
+                            "2018_Lamnidis_Fennoscandia.fam:md5,90c1b106d15bceccc1e25c34d3060d75",
+                            "2018_Lamnidis_Fennoscandia.janno:md5,26aefa65ac7ce4c070503cde7f7a1297",
+                            "CHANGELOG.txt:md5,3d4d9c8c1c4395d086445193f29c380f",
+                            "POSEIDON.yml:md5,85f148be29824c8f9136cd4cb12d4462"
+                        ],
+                        "0"
+                    ]
+                ],
+                "versions_trident": [
+                    [
+                        "TRIDENT_VALIDATE",
+                        "trident",
+                        "2.2.2.1"
+                    ],
+                    [
+                        "TRIDENT_VALIDATE",
+                        "trident",
+                        "2.2.2.1"
+                    ]
+                ]
+            }
+        ],
+        "timestamp": "2026-11-03T14:43:00.252986",
+        "meta": {
+            "nf-test": "0.9.5",
+            "nextflow": "26.10.4"
+        }
+    }
+}