Skip to content
Open
Show file tree
Hide file tree
Changes from all commits
Commits
File filter

Filter by extension

Filter by extension

Conversations
Failed to load comments.
Loading
Jump to
Jump to file
Failed to load files.
Loading
Diff view
Diff view
36 changes: 36 additions & 0 deletions Mathlib/Analysis/Calculus/BumpFunction/FiniteDimension.lean
Original file line number Diff line number Diff line change
Expand Up @@ -26,6 +26,9 @@ in `IsOpen.exists_contDiff_support_eq`.

Then we use this construction to construct bump functions with nice behavior, by convolving
the indicator function of `closedBall 0 1` with a function as above with `s = ball 0 D`.

Finally, `Real.exists_contDiff_indicator_Icc_le_le_indicator_Ioo` provides smooth cutoffs on `ℝ`
lying between the indicator functions of two nested intervals.
-/

@[expose] public section
Expand Down Expand Up @@ -526,3 +529,36 @@ instance (priority := 100) {E : Type*} [NormedAddCommGroup E] [NormedSpace ℝ E
end ExistsContDiffBumpBase

end

/-- A smooth cutoff on `ℝ`: if `a < b ≤ c < d`, there is a smooth function `ψ` with compact
support contained in `Ioo a d` such that `𝟙_[b, c] ≤ ψ ≤ 𝟙_(a, d)`. In particular,
`∫ ψ ∈ [c - b, d - a]`. -/
theorem Real.exists_contDiff_indicator_Icc_le_le_indicator_Ioo {a b c d : ℝ} (hab : a < b)
(hbc : b ≤ c) (hcd : c < d) :
∃ ψ : ℝ → ℝ, ContDiff ℝ ∞ ψ ∧ HasCompactSupport ψ ∧ tsupport ψ ⊆ Ioo a d ∧
(Icc b c).indicator 1 ≤ ψ ∧ ψ ≤ (Ioo a d).indicator 1 ∧
∫ x, ψ x ∈ Icc (c - b) (d - a) := by
let ψ : ContDiffBump ((b + c) / 2) :=
⟨(c - b) / 2 + min (b - a) (d - c) / 3, (c - b) / 2 + 2 * min (b - a) (d - c) / 3,
by grind, by grind⟩
have hts : tsupport ψ ⊆ Ioo a d := by
grind [ψ.tsupport_eq, Real.closedBall_eq_Icc]
have hle : (Icc b c).indicator 1 ≤ ψ := fun x ↦ by
by_cases hx : x ∈ Icc b c
· rw [indicator_of_mem hx, Pi.one_apply, ψ.one_of_mem_closedBall ?h]
case h => grind [Real.closedBall_eq_Icc]
· simpa [indicator_of_notMem hx] using ψ.nonneg
have hle' : ⇑ψ ≤ (Ioo a d).indicator 1 := fun x ↦ by
by_cases hx : x ∈ Ioo a d
· rw [indicator_of_mem hx, Pi.one_apply]
exact ψ.le_one
· rw [indicator_of_notMem hx, image_eq_zero_of_notMem_tsupport fun h ↦ hx (hts h)]
have hint : Integrable ψ := ψ.continuous.integrable_of_hasCompactSupport ψ.hasCompactSupport
have hind {s : Set ℝ} (hs : MeasurableSet s) (hs' : volume s ≠ ⊤) :
Integrable (s.indicator (1 : ℝ → ℝ)) :=
(integrable_indicator_iff hs).2 (integrableOn_const hs' (by simp))
refine ⟨ψ, ψ.contDiff, ψ.hasCompactSupport, hts, hle, hle', ?_, ?_⟩
· rw [← volume_real_Icc_of_le hbc, ← integral_indicator_one measurableSet_Icc]
exact integral_mono (hind measurableSet_Icc (by simp)) hint hle
· rw [← volume_real_Ioo_of_le (by linarith), ← integral_indicator_one measurableSet_Ioo]
exact integral_mono hint (hind measurableSet_Ioo (by simp)) hle'
4 changes: 4 additions & 0 deletions Mathlib/Analysis/Distribution/SchwartzSpace/Basic.lean
Original file line number Diff line number Diff line change
Expand Up @@ -531,6 +531,10 @@ instance instLocallyConvexSpace : LocallyConvexSpace ℝ 𝓢(E, F) :=
instance instFirstCountableTopology : FirstCountableTopology 𝓢(E, F) :=
(schwartz_withSeminorms ℝ E F).firstCountableTopology

@[fun_prop]
theorem continuous_seminorm (k n : ℕ) : Continuous (SchwartzMap.seminorm 𝕜 k n : 𝓢(E, F) → ℝ) :=
(schwartz_withSeminorms 𝕜 E F).continuous_seminorm (k, n)

end Topology

@[fun_prop]
Expand Down
24 changes: 24 additions & 0 deletions Mathlib/Analysis/Fourier/RiemannLebesgueLemma.lean
Original file line number Diff line number Diff line change
Expand Up @@ -38,6 +38,8 @@ equivalence to an inner-product space.
with its unique Hausdorff topological vector space structure), and `W` the dual of `V`, the
function `fun w : W ↦ ∫ v : V, exp (2 * π * w v * I) • f v` tends to along `cocompact W`.
- `Real.tendsto_integral_exp_smul_cocompact`: special case of functions on `ℝ`.
- `Real.tendsto_integral_cpow_mul_I_smul_atTop`: multiplicative form for functions on `ℝ`,
`∫ t, x ^ (t * I) • f t → 0` as `x → ∞`.
- `Real.zero_at_infty_fourierIntegral` and `Real.zero_at_infty_vector_fourierIntegral`:
reformulations explicitly using the Fourier integral.
-/
Expand Down Expand Up @@ -212,6 +214,28 @@ theorem Real.tendsto_integral_exp_smul_cocompact (f : ℝ → E) :
theorem Real.zero_at_infty_fourier (f : ℝ → E) : Tendsto (𝓕 f) (cocompact ℝ) (𝓝 0) :=
tendsto_integral_exp_inner_smul_cocompact f

/-- For `0 < x`, the character `t ↦ x ^ (t * I)` of `ℝ` is `t ↦ 𝐞 (t * log x / (2 * π))`. -/
theorem Real.fourierChar_mul_log_div_two_pi {x : ℝ} (hx : 0 < x) (t : ℝ) :
(𝐞 (t * Real.log x / (2 * π)) : ℂ) = (x : ℂ) ^ (t * I) := by
rw [Real.fourierChar_apply, cpow_def_of_ne_zero (ofReal_ne_zero.mpr hx.ne'),
← ofReal_log hx.le]
congr 1
push_cast
field

/-- The Riemann-Lebesgue lemma for functions on `ℝ`, in multiplicative form: the integrals
`∫ t, x ^ (t * I) • f t` tend to `0` as `x → ∞`. -/
theorem Real.tendsto_integral_cpow_mul_I_smul_atTop (f : ℝ → E) :
Tendsto (fun x : ℝ ↦ ∫ t : ℝ, (x : ℂ) ^ (t * I) • f t) atTop (𝓝 0) := by
have h : Tendsto (fun x ↦ -(log x / (2 * π))) atTop (cocompact ℝ) :=
(tendsto_neg_atTop_atBot.comp
(tendsto_log_atTop.atTop_div_const (by positivity))).mono_right atBot_le_cocompact
refine ((zero_at_infty_fourier f).comp h).congr' ?_
filter_upwards [eventually_gt_atTop 0] with x hx
simp only [Function.comp_apply, fourier_real_eq]
refine integral_congr_ae (.of_forall fun t ↦ ?_)
simp [← mul_div_assoc, Circle.smul_def, fourierChar_mul_log_div_two_pi hx]

/-- Riemann-Lebesgue lemma for functions on a finite-dimensional inner-product space, formulated
via dual space. **Do not use** -- it is only a stepping stone to
`tendsto_integral_exp_smul_cocompact` where the inner-product-space structure isn't required. -/
Expand Down
8 changes: 8 additions & 0 deletions Mathlib/Analysis/SpecialFunctions/Exp.lean
Original file line number Diff line number Diff line change
Expand Up @@ -235,6 +235,14 @@ theorem tendsto_exp_atBot : Tendsto exp atBot (𝓝 0) :=
theorem tendsto_exp_atBot_nhdsGT : Tendsto exp atBot (𝓝[>] 0) :=
tendsto_inf.2 ⟨tendsto_exp_atBot, tendsto_principal.2 <| Eventually.of_forall exp_pos⟩

/-- If `f : ℝ → E` has compact support and vanishes near `0`, then `f ∘ exp` has compact
support. -/
theorem _root_.HasCompactSupport.comp_exp {E : Type*} [Zero E] {f : ℝ → E}
(hf : HasCompactSupport f) (h : 0 ∉ tsupport f) : HasCompactSupport (f ∘ exp) := by
simp only [hasCompactSupport_iff_eventuallyEq, coclosedCompact_eq_cocompact,
cocompact_eq_atBot_atTop] at hf ⊢
exact ⟨tendsto_exp_atBot <| notMem_tsupport_iff_eventuallyEq.mp h, tendsto_exp_atTop hf.2⟩

@[simp]
theorem isBoundedUnder_ge_exp_comp (l : Filter α) (f : α → ℝ) :
IsBoundedUnder (· ≥ ·) l fun x => exp (f x) :=
Expand Down
16 changes: 16 additions & 0 deletions Mathlib/MeasureTheory/Integral/IntegralEqImproper.lean
Original file line number Diff line number Diff line change
Expand Up @@ -501,6 +501,22 @@ theorem AECover.integral_eq_of_tendsto_of_nonneg_ae [l.NeBot] [l.IsCountablyGene
have hfi' : Integrable f μ := hφ.integrable_of_integral_tendsto_of_nonneg_ae I hfi hnng htendsto
hφ.integral_eq_of_tendsto I hfi' htendsto

/-- If `f` vanishes in a neighborhood of `a`, then `∫ x in Ioi b, f x ∂μ = ∫ x in Ioi a, f x ∂μ`
for all `b` close enough to `a`. -/
theorem eventually_setIntegral_Ioi_eq_of_eventuallyEq_zero [LinearOrder α] [TopologicalSpace α]
[OrderTopology α] [OpensMeasurableSpace α] {f : α → E} {a : α} (hf : f =ᶠ[𝓝 a] 0) :
∀ᶠ b in 𝓝 a, ∫ x in Ioi b, f x ∂μ = ∫ x in Ioi a, f x ∂μ := by
filter_upwards [tendsto_smallSets_iff.mp (tendsto_const_nhds.uIcc tendsto_id) _ hf] with b hb
rw [← integral_indicator measurableSet_Ioi, ← integral_indicator measurableSet_Ioi]
congr 1 with x
simp only [indicator_apply, mem_Ioi]
by_cases hx : x ∈ uIcc a b
· simp [show f x = 0 from hb hx]
split_ifs with h₁ h₂ h₂ <;> first
| rfl
| exact (hx (mem_uIcc.mpr (.inr ⟨h₁.le, not_lt.mp h₂⟩))).elim
| exact (hx (mem_uIcc.mpr (.inl ⟨h₂.le, not_lt.mp h₁⟩))).elim

end Integral

section IntegrableOfIntervalIntegral
Expand Down
13 changes: 13 additions & 0 deletions Mathlib/NumberTheory/LSeries/SumCoeff.lean
Original file line number Diff line number Diff line change
Expand Up @@ -94,6 +94,19 @@ theorem LSeriesSummable_of_sum_norm_bigO_and_nonneg
LSeriesSummable (fun n ↦ f n) s :=
LSeriesSummable_of_sum_norm_bigO (by simpa [abs_of_nonneg (hf _)]) hr hs

/-- If `f` takes nonnegative real values and satisfies the Chebyshev-type bound
`∑ k ∈ range n, f k ≤ C * n` for all `n`, then the L-series `LSeries f` converges at `s : ℂ`
for all `s` such that `1 < s.re`. -/
theorem LSeriesSummable_of_sum_range_le_and_nonneg {f : ℕ → ℝ} {C : ℝ}
(hO : ∀ n, ∑ k ∈ range n, f k ≤ C * n) (hf : ∀ n, 0 ≤ f n) (hs : 1 < s.re) :
LSeriesSummable (fun n ↦ f n) s := by
refine LSeriesSummable_of_sum_norm_bigO_and_nonneg (r := 1) ?_ hf zero_le_one hs
refine isBigO_of_le' (c := 2 * C) _ fun n ↦ ?_
rw [Real.norm_of_nonneg (sum_nonneg fun k _ ↦ hf k), Real.rpow_one, Real.norm_natCast]
calc
_ ≤ ∑ k ∈ range (2 * n), f k := sum_le_sum_of_subset_of_nonneg (by grind) fun k _ _ ↦ hf k
_ ≤ _ := (hO (2 * n)).trans_eq (by grind)

end summable

section integralrepresentation
Expand Down
Loading