ReasonKit-think/justfile at main · reasonkit/ReasonKit-think · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# reasonkit-think — use `just` per project conventions (CONS-017)

default:
    @just --list

build:
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}" cargo build --release

check:
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}" cargo fmt --check
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}" cargo clippy --all-targets --all-features -- -D warnings
    just unit

unit:
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}" cargo test --all-targets --all-features
    python3 -m unittest discover -s tests -p "test_*.py" -v

eval: build
    python3 evals/run_contract_evals.py --binary "${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}/release/reasonkit-think-mcp"

audit:
    cargo audit --deny warnings

package-check:
    CARGO_TARGET_DIR="{{ justfile_directory() }}/target/package-check" cargo package --locked

registry-check:
    uvx --from check-jsonschema==0.38.0 check-jsonschema --schemafile https://static.modelcontextprotocol.io/schemas/2025-12-11/server.schema.json server.json

dist-check:
    @test "$(dist --version)" = "cargo-dist 0.32.0"
    @dist manifest --artifacts=local --output-format=json --no-local-paths > /dev/null

dist-host-check: dist-check
    dist build --artifacts=host

ci: check eval audit package-check registry-check dist-check dist-host-check

fmt:
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-{{ justfile_directory() }}/target}" cargo fmt

# Rebuild release binary + validate workspace MCP wiring + smoke test.
mcp-refresh:
    #!/usr/bin/env bash
    set -euo pipefail
    ROOT="{{ justfile_directory() }}"
    CARGO_TARGET_DIR="${CARGO_TARGET_DIR:-$ROOT/target}" cargo build --release
    python3 -m json.tool "$ROOT/../.mcp.json" >/dev/null
    test -x "$ROOT/target/release/reasonkit-think-mcp"
    python3 "$ROOT/scripts/smoke_test.py"
    echo "reasonkit-think MCP refresh OK"

# Re-fetch reference implementation (optional; shallow)
bootstrap-reference:
    #!/usr/bin/env bash
    set -euo pipefail
    REF="reference/mcp-sequentialthinking-tools"
    rm -rf "$REF"
    git clone --depth 1 https://github.com/spences10/mcp-sequentialthinking-tools.git "$REF"
    rm -rf "$REF/.git"