stats/commits-over-time.plot at master · curl/stats · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# SVG output
load "stats/terminal.include"

# title
set title "Commits" font ",48"
# where's the legend
set key top left

# Identify the axes
#set xlabel "Time"
set ylabel "Number of commits"

set style line 1 \
    linecolor rgb '#40c0ad' \
    linetype 1 linewidth 2
set style line 2 \
    linecolor rgb '#c04040' \
    linewidth 2
set style line 3 \
    linecolor rgb '#4040c0' \
    linewidth 2

set grid
unset border

# time formated using this format
set timefmt "%Y-%m-%d"
set xdata time
set xtics rotate time 1 years nomirror out
unset mxtics
set ytics nomirror

load "stats/logo.include"

# set the format of the dates on the x axis
set format x "%Y"
set format y "%.0s%c"
set datafile separator ";"
plot ARG1.'/commits-over-time.csv' using 1:3 with lines linestyle 2 title "Daniel's commits", \
  ARG1.'/commits-over-time.csv' using 1:4 with lines linestyle 3 title "Everyone else's commits", \
  ARG1.'/commits-over-time.csv' using 1:2 with lines linestyle 1 title "All commits"