String parsing error

[parix3]

A string starting with a double apostrophe is incorrectly parsed. All such literals are truncated. For example "'bla-bla" bla-bla' The error is directly in the function TPasSyntaxTreeBuilder.DequoteString(const S: string): string;

[Ilia-Nenashev-devX]

My try to fix, according to https://docwiki.embarcadero.com/RADStudio/Athens/en/String_Types_(Delphi)#Long_and_Multiline_String_Literals:

function TPasSyntaxTreeBuilder.DequoteString(const S: string): string;

  function Min(A, B: Integer): Integer; // TODO: use System.Math instead
  begin    
    if A < B then
      Result := A
    else
      Result := B;
  end;  

var
  QuoteCount, CharIndex, LineIndex: Integer;
  Lines: TStringList;
  Line, LastLine: string;
begin
  QuoteCount := 0;
  for CharIndex := Low(S) to High(S) do
    if S[CharIndex] = '''' then
      Inc(QuoteCount)
    else
      Break;

  if (QuoteCount = 1) or (QuoteCount mod 2 = 0) or ((QuoteCount < S.Length) and (S[QuoteCount + 1] <> #13)) then
  begin
    Result := AnsiDequotedStr(S, '''');
    Exit;
  end;

  Lines := TStringList.Create;
  try
    Lines.TrailingLineBreak := False;
    Lines.Text := S.Substring(QuoteCount + 1);
    LastLine := Lines[Lines.Count - 1];
    if LastLine.Length < QuoteCount then
      raise EParserException.Create(Lexer.PosXY.Y, Lexer.PosXY.X, Lexer.FileName, Format('Last line in multiline string shorter than starting %d quotes', [QuoteCount]));

    for CharIndex := LastLine.Length - QuoteCount + 1 to LastLine.Length do
      if LastLine[CharIndex] <> '''' then
        raise EParserException.Create(Lexer.PosXY.Y, Lexer.PosXY.X, Lexer.FileName, Format('Invalid char ''%s'' (#%d) at the end of multiline string last line', [LastLine[CharIndex], Ord(LastLine[CharIndex])]));

    SetLength(LastLine, LastLine.Length - QuoteCount); // Cut the quotes

    for CharIndex := 1 to LastLine.Length do
      if not CharInSet(LastLine[CharIndex], [' ', #9]) then
        raise EParserException.Create(Lexer.PosXY.Y, Lexer.PosXY.X, Lexer.FileName, Format('Invalid ident char ''%s'' (#%d) in multiline string last line', [LastLine[CharIndex], Ord(LastLine[CharIndex])]));

    for LineIndex := 1 to Lines.Count - 2 do
    begin
      Line := Lines[LineIndex];
      for CharIndex := 1 to Min(Line.Length, LastLine.Length) do
        if Line[CharIndex] <> LastLine[CharIndex] then
          raise EParserException.Create(Lexer.PosXY.Y, Lexer.PosXY.X, Lexer.FileName, Format('Invalid ident char ''%s'' (#%d) in multiline string line %d', [Line[CharIndex], Ord(Line[CharIndex]), LineIndex]));
      Lines[LineIndex] := Line.Substring(LastLine.Length);
    end;
    Lines.Delete(Lines.Count - 1);
    Lines.Delete(0);
    Result := Lines.Text;
  finally
    Lines.Free;
  end;
end;